一、实验目的：
学习MSP430端口输入输出方法，测试2个按钮和发光二极管的使用，其中1个按钮用来开启发光二极管的闪烁，另外1个按钮用来停止发光二极管的闪烁。按钮的检测由P1，P2中断来完成。
二、实验设备：
MSP430F1121实验板一个，3V电源一个，JTAG接口一个。
三、实验电路原理图：
四、实验内容：
五、参考程序：
;******************************************************************************
;功能：此程序用来测试2个按钮和发光二极管的使用，1个按钮用来开启发光二极管的闪烁，1个
; 按钮用来停止发光二极管的闪烁。按钮的检测由P1，P2中断来完成。
;使用资源：P2.4控制发光二极管，P2.1用于控制第一个按钮，P1.2控制第二个按钮
;******************************************************************************
#include "msp430x11x1.h"
;------------------------------------------------------------------------------
ORG 0F000h ;
;------------------------------------------------------------------------------
RESET mov.w #300h,SP ; 初始化堆栈指针
StopWDT mov.w #WDTPW+WDTHOLD,&WDTCTL ; 关闭看门狗
SetupP2 bis.b #010h,&P2DIR ; 设置P2.4为输出
mov.b #01h,&200h ; 按钮开关标致存储状态
Setp1key bis.b #BIT2,&P1DIR ;设置P1.2为输出
bis.b #BIT2,&P1OUT ;输出高电平
bic.b #BIT2,&P1DIR ;设置P1.2为输入
bis.b #BIT2,&P1IE ;开P1.2中断
bis.b #BIT2,&P1IES ;设置p1.2为下降沿中断
mov.b #00h,&P1IFG ;清中断标致
Setp2key bis.b #BIT1,&P2DIR ;设置P2.1为输出
bis.b #BIT1,&P2OUT ;输出高电平
bic.b #BIT1,&P2DIR ;设置P2.1为输入
bis.b #BIT1,&P2IE ;开P2.1中断
bis.b #BIT1,&P2IES ;设置P2.1为下降沿中断
mov.b #00h,&P2IFG ;清中断标致
EINT
Mainloop bit.b #BIT0,&200H ;测试200H中的数据是否为1，是则闪烁
JNC Mainloop
xor.b #010h,&P2OUT ; 把 P2.4取反输出
Wait mov.w #050000,R15 ; 延时
L1 dec.w R15 ;
jnz L1 ;
jmp Mainloop ;
;
;----------------------------------------------中断程序
P1KEY MOV.B #00h,&P1IFG ;清中断标致
CALL #KEY1 ;测试按钮状态
JC KEYEND1
CALL #DELAY10MS ;延时
CALL #KEY1 ;测试按钮状态
JC KEYEND1
MOV.B #01H,&200H ;把1写入200H中
;
KEYEND1 RETI
KEY1 BIT.B #BIT2,&P1IN ;按钮测试
RET
;----------------------------------------------中断程序
P2KEY MOV.B #00h,&P2IFG ;清中断标致
CALL #KEY2 ;测试按钮状态
JC KEYEND2
CALL #DELAY10MS ;延时
CALL #KEY2 ;测试按钮状态
JC KEYEND2
MOV.B #00H,&200H ;把0写入200H中
BIS.B #010h,&P2OUT ;熄灭二极管
;
KEYEND2 RETI
KEY2 BIT.B #BIT1,&P2IN ;按钮测试
RET
;--------------------------------------------- 延时程序
DELAY10MS mov.w #520,R15 ; Delay to R15
L11 dec.w R15 ; Decrement R15
jnz L11 ; Delay over?
RET
;-----------------------------------------------------------------------------
; Interrupt Vectors Used MSP430x11x1
;-----------------------------------------------------------------------------
ORG 0FFFEh ; MSP430 RESET Vector
DW RESET ;
ORG 0FFE4H ;PORT1_VECTOR
DW P1KEY
ORG 0FFE6H ;PORT2_VECTOR
DW P2KEY
END
|
