一、实验目的：
通过液晶显示器接口电路的设计与编程，掌握液晶显示器的原理，学会使用液晶显示器，并把它嵌入到便携式电子信息产品中。
二、实验设备：
51通用实验板一个，1602液晶一个，51仿真器一个，12V电源一个。
三、实验电路原理图：
四、实验内容：
五、参考程序：
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;功能： LCD 1602液晶显示实验
;资源使用：p0口用于数据口，P2.0为RS P2.1为R/W P2.2为E
; RS为寄存器选择位,RS=1选择数据寄存器,RS=0选择指令寄存器
; E为使能信号，下降沿触发。
; R/W为读写信号，1为读，0为写
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
ORG 0000H
AJMP MAIN
ORG 0030H
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
MAIN: LCALL LCDINT
MOV DPTR, #WORD1;显示第一行数据
MOV R2,#80H ;1000 0000 DDRAM地址设置为00h
LCALL WRC
MOV R4,#16
LCALL WRN
MOV DPTR,#WORD2 ;显示第二行数据
MOV R2,#0C0H ;1100 0000 DDRAM地址设置为40h
LCALL WRC
MOV R4,#16
LCALL WRN
SJMP $
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;液晶初始化
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
LCDINT: MOV R2,#38H ;0011 1000功能设置:采用8位数据总线,采用双行显示,采用5X7点阵
LCALL WRC ;写入指令
ACALL DELAY ;延时程序
MOV R2,#0CH ;0000 1100光标/显示移位:1为显示移位,0为光标移位
ACALL WRC
ACALL DELAY
MOV R2,#06H ;0000 0110输入模式:1为AC增量模式,0为AC自减模式,显示整体不移动
ACALL WRC
ACALL DELAY
MOV R2,#01H ;清屏
LCALL WRC
ACALL DELAY
RET
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;写入控制指令,数据放在R2中
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
WRC:
ACALL BUSY
CLR P2.0
CLR P2.1
CLR P2.2
MOV A,R2
MOV P0,A
NOP
SETB P2.2;E使用信号
NOP
CLR P2.2;E使用能下降沿触发
RET
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;忙闲测试
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
BUSY:
CLR P2.0;RS=0读寄存器 读BF
SETB P2.1; R/W 1为读,0为写
NOP
SETB P2.2;E
NOP
MOV A,P0;读取P0口
JB ACC.7,BUSY
CLR P2.2
RET
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;写入数据
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
WRD:
ACALL BUSY
SETB P2.0
CLR P2.1
CLR P2.2
MOV A,R2
MOV P0,A
NOP
SETB P2.2
NOP
CLR P2.2
RET
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;写入N个数据,R2为要显示的数据,R4为显示个数
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
WRN:
CLR A
MOVC A,@A+DPTR
INC DPTR
MOV R2,A
LCALL WRD
DJNZ R4,WRN
RET
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;程序延时
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
DELAY: MOV R6,#01H
DL0: MOV R7,#250
DL1: NOP
NOP
DJNZ R7,DL1
DJNZ R6,DL0
RET
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;每行要显示的数据
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
WORD1: DB 20H,20H,20H,30H,31H,32H,33H,34H,35H,36H,37H,38H,39H,20H,20H,20H
WORD2: DB 20H,4FH,55H,52H,20H,55H,4EH,49H,56H,45H,52H,53H,49H,54H,59H,20H
END |
